DOS批处理 - 函数教程

阅读量：5259 次

发布时间：2019-06-14

本文共 14598 字，大约阅读时间需要 48 分钟。

DOS Batch - Function Tutorial

What it is, why it`s important and how to write your own.

Description:

The assumption is: A batch script snippet can be named a function when:

... it has a callable entrance point.

... on completion execution continues right after the command that initially called the function.

... it works the same no matter from where it`s being called, even when it calls itself recursively.

... the variables used within a function do not conflict with variables outside the function.

... it exchanges data with the calling code strictly through input and output variables or a return code.

The benefits behind functions are:

Keep the main script clean

Hide complexity in reusable functions

Test functions independently from the main script

Add more functionality to your batch script simply by adding more functions at the bottom

Don`t worry about the function implementation, just test it and use it


	What is a function?
	How to invoke a function?
	An Example showing how it works.
	How to pass arguments to the function?
	How to retrieve function arguments within the function?
	An Example showing how it works.
	The classic way of returning values and the limitations.
	Let the caller determine how to return the function result and avoid the need of dedicated variables.
	An Example showing how it works.
	How to avoid name conflicts and keep variable changes local to the function?
	How to pass return values over the ENDLOCAL barrier?
	Tadaaah!!!
	Defining a standard format for a DOS batch function
	What it is, why it`s important and how to write your own.

2008-01-01

Create a Function - What is a function

Description: In DOS you write a function by surrounding a group of command by a label and a GOTO:EOF command. A single batch file can contain multiple functions defined like this. The label becomes the function name.

Script:

01.
02.
03.
04.

:myDosFunc    - here starts my function identified by it`s label
echo. here the myDosFunc function is executing a group of commands
echo. it could do a lot of things
GOTO:EOF

2008-01-01

Call a Function - How to invoke a function

Description: A function can be called with the CALL command followed by the function label.

Script:

01.

call:myDosFunc

2008-01-01

Example - Calling a Function - An Example showing how it works

Description:

The use of batch functions will divide the script into two sections.

The main script: starting at line 1 ending with a GOTO:EOF command that terminates the script.

The function section: filling the second half of the batch file with one or more functions to be callable from the main script.

Script:

Download:

01.
02.
03.
04.
05.
06.
07.
08.
09.
10.
11.
12.
13.
14.
15.
16.

@echo off
echo.going to execute myDosFunc
call:myDosFunc
echo.returned from myDosFunc
echo.&pause&goto:eof
::--------------------------------------------------------
::-- Function section starts below here
::--------------------------------------------------------
:myDosFunc    - here starts my function identified by it`s label
echo.  here the myDosFunc function is executing a group of commands
echo.  it could do a lot of things
goto:eof

Script Output:

Script Output

going to execute myDosFunc  here the myDosFunc function is executing a group of commands  it could do a lot of thingsreturned from myDosFunc Press any key to continue . . .

2008-01-01

Passing Function Arguments - How to pass arguments to the function

Description:

Just as the DOS batch file itself can have arguments, a function can be called with arguments in a similar way. Just list all arguments after the function name in the call command.

Use a space or a comma to separate arguments.

Use double quotes for string arguments with spaces.

Script:

01.
02.
03.

call:myDosFunc 100 YeePEE
call:myDosFunc 100 "for me"
call:myDosFunc 100,"for me"

2008-01-01

Parsing Function Arguments - How to retrieve function arguments within the function

Description:

Just as the DOS batch file itself retrieves arguments via %1 â¦ %9 a function can parse it`s arguments the same way. The same rules apply.

Let`s modify our previews example to use arguments.

To strip of the double quotes in an arguments value the tilde modifier, i.e. use %~2 instead of %2.

Script:

01.
02.
03.
04.
05.

:myDosFunc    - here starts myDosFunc identified by it`s label
echo.
echo. here the myDosFunc function is executing a group of commands
echo. it could do %~1 of things %~2.
goto:eof

2008-01-01

Example - Function with Arguments - An Example showing how it works

Description:

The following example demonstrates how to pass arguments into a DOS function. The :myDosFunc function is being called multiple times with different arguments.

Note: The last call to myDosFunc doesn`t use double quotes for the second argument. Subsequently "for" and "me" will be handled as two separate arguments, whereas the third argument "me" is not being used within the function.

Script:

Download:

01.
02.
03.
04.
05.
06.
07.
08.
09.
10.
11.
12.
13.
14.
15.
16.
17.
18.
19.
20.

@echo off
echo.going to execute myDosFunc with different arguments
call:myDosFunc 100 YeePEE
call:myDosFunc 100 "for me"
call:myDosFunc 100,"for me"
call:myDosFunc 100,for me
echo.&pause&goto:eof
::--------------------------------------------------------
::-- Function section starts below here
::--------------------------------------------------------
:myDosFunc    - here starts my function identified by it's label
echo.
echo. here the myDosFunc function is executing a group of commands
echo. it could do %~1 of things %~2.
goto:eof

Script Output:

Script Output

going to execute myDosFunc with different arguments  here the myDosFunc function is executing a group of commands it could do 100 of things YeePEE.  here the myDosFunc function is executing a group of commands it could do 100 of things for me.  here the myDosFunc function is executing a group of commands it could do 100 of things for me.  here the myDosFunc function is executing a group of commands it could do 100 of things for. Press any key to continue . . .

2008-01-01

Returning Values the Classic Way - The classic way of returning values and the limitations

Description:

The CALL command doesn`t support return values as known by other programming languages.

The classic walkaround is to have the function store the return value into a environment variable. The calling script can use this variable when the function returns. The :myGetFunc function below demonstrates how the variable var1 gets the "DosTips" string assigned which can then be used in the calling function.

Note: The var1 variable is reserved for this particular function. Any data stored in var1 by the calling function before calling :myGetVar will be overwritten.

Usage:

01.
02.
03.
04.

set "var1=some hopefully not important string"
echo.var1 before: %var1%
call:myGetFunc
echo.var1 after : %var1%

Script:

01.
02.
03.

:myGetFunc    - get a value
set "var1=DosTips"
goto:eof

Script Output:

Script Output

var1 before: some hopefully not important stringvar1 after : DosTips

2008-01-01

Returning Values via References - Let the caller determine how to return the function result and avoid the need of dedicated variables

Description:

Instead of using "global" variables for return value, the function can use one of it`s arguments as variable reference. The caller can then pass a variable name to the function and the function can store the result into this variable making use of the command line expansion of the command processor:

Note: The var1 variable is not reserved for this articular function. Any variable can be passed to the function the caller has full control.

Usage:

01.
02.

call:myGetFunc var1
echo.var1 after : %var1%

Script:

01.
02.
03.

:myGetFunc    - passing a variable by reference
set "%~1=DosTips"
goto:eof

Script Output:

Script Output

var1 after : DosTips

2008-01-01

Example - Returning Values using Variable Reference - An Example showing how it works

Description:

This code shows how the var1 variable is being passed into a :myGetFunc function simply by passing the variable name. Within the :myGetFunc function the command processor works like this:

Reads the set command into memory: set "%~1=DosTips"

Expand the variables, i.e. %~1 like this: set "var1=DosTips"

Finally execute the command and assign the new string to var1

Script:

Download:

01.
02.
03.
04.
05.
06.
07.
08.
09.
10.
11.
12.
13.
14.
15.
16.
17.

@echo off
set "var1=CmdTips"
echo.var1 before: %var1%
call:myGetFunc var1
echo.var1 after : %var1%
echo.&pause&goto:eof
::--------------------------------------------------------
::-- Function section starts below here
::--------------------------------------------------------
:myGetFunc    - passing a variable by reference
set "%~1=DosTips"
goto:eof

Script Output:

Script Output

var1 before: CmdTipsvar1 after : DosTips Press any key to continue . . .

2008-01-01

Local Variables in Functions - How to avoid name conflicts and keep variable changes local to the function

Description:

The SETLOCAL causes the command processor to backup all environment variables. The variables can be restored by calling ENDLOCAL. Changes made im between are local to the current batch. ENDLOCAL is automatically being called when the end of the batch file is reached, i.e. by calling GOTO:EOF.

Localizing variables with SETLOCAL allows using variable names within a function freely without worrying about name conflicts with variables used outside the function.

Script:

Download:

01.
02.
03.
04.
05.
06.
07.
08.
09.
10.
11.
12.
13.
14.
15.
16.
17.
18.
19.
20.
21.
22.

@echo off
set "aStr=Expect no changed, even if used in function"
set "var1=No change for this one.  Now what?"
echo.aStr before: %aStr%
echo.var1 before: %var1%
call:myGetFunc var1
echo.aStr after : %aStr%
echo.var1 after : %var1%
echo.&pause&goto:eof
::--------------------------------------------------------
::-- Function section starts below here
::--------------------------------------------------------
:myGetFunc    - passing a variable by reference
SETLOCAL
set "aStr=DosTips"
set "%~1=%aStr%"
ENDLOCAL
goto:eof

Script Output:

Script Output

aStr before: Expect no changed, even if used in functionvar1 before: No change for this one.  Now what?aStr after : Expect no changed, even if used in functionvar1 after : No change for this one.  Now what? Press any key to continue . . .

2008-01-01

Returning Local Variables - How to pass return values over the ENDLOCAL barrier

Description:

The question is: When localizing a function via SETLOCAL and ENDLOCAL, how to return a value that was calculated before executing ENDLOCAL when ENDLOCAL restores all variables back to its original state?

The answer comes with "variable expansion". The command processor expands all variables of a command before executing the command. Letting the command processor executing ENDLOCAL and a SET command at once solves the problem. Commands can be grouped within brackets.

Script:

Download:

01.
02.
03.
04.
05.
06.
07.
08.
09.
10.
11.
12.
13.
14.
15.
16.
17.
18.
19.
20.
21.
22.
23.
24.
25.
26.
27.
28.
29.

@echo off
set "aStr=Expect no changed, even if used in function"
set "var1=Expect changed"
echo.aStr before: %aStr%
echo.var1 before: %var1%
call:myGetFunc var1
echo.aStr after : %aStr%
echo.var1 after : %var1%
echo.&pause&goto:eof
::--------------------------------------------------------
::-- Function section starts below here
::--------------------------------------------------------
:myGetFunc    - passing a variable by reference
SETLOCAL
set "aStr=DosTips"
( ENDLOCAL
    set "%~1=%aStr%"
)
goto:eof
:myGetFunc2    - passing a variable by reference
SETLOCAL
set "aStr=DosTips"
ENDLOCAL&set "%~1=%aStr%"       &rem THIS ALSO WORKS FINE
goto:eof

Script Output:

Script Output

aStr before: Expect no changed, even if used in functionvar1 before: Expect changedaStr after : Expect no changed, even if used in functionvar1 after : DosTips Press any key to continue . . .

2008-01-01

Recursive Functions - Tadaaah!!!

Description:

Being able to completely encapsulate the body of a function by keeping variable changes local to the function and invisible to the caller we are now able to call a function recursively making sure each level of recursion works with its own set of variables even thought variable names are being reused.

Example: The next example below shows how to calculate a Fibonacci number recursively. The recursion stops when the Fibonacci algorism reaches a number greater or equal to a given input number.

The example starts with the numbers 0 and 1 the :myFibo function calls itself recursively to calculate the next Fibonacci number until it finds the Fibonacci number greater or equal 1000000000.

The first argument of the myFibo function is the name of the variable to store the output in. This variable must be initialized to the Fibonacci number to start with and will be used as current Fibonacci number when calling the function and will be set to the subsequent Fibonacci number when the function returns.

Script:

Download:

01.
02.
03.
04.
05.
06.
07.
08.
09.
10.
11.
12.
13.
14.
15.
16.
17.
18.
19.
20.
21.
22.
23.
24.
25.
26.
27.
28.
29.

@echo off
set "fst=0"
set "fib=1"
set "limit=1000000000"
call:myFibo fib,%fst%,%limit%
echo.The next Fibonacci number greater or equal %limit% is %fib%.
echo.&pause&goto:eof
::--------------------------------------------------------
::-- Function section starts below here
::--------------------------------------------------------
:myFibo  -- calculate recursively the next Fibonacci number greater or equal to a limit
::       -- %~1: return variable reference and current Fibonacci number
::       -- %~2: previous value
::       -- %~3: limit
SETLOCAL
set /a "Number1=%~1"
set /a "Number2=%~2"
set /a "Limit=%~3"
set /a "NumberN=Number1 + Number2"
if /i %NumberN% LSS %Limit% call:myFibo NumberN,%Number1%,%Limit%
(ENDLOCAL
    IF "%~1" NEQ "" SET "%~1=%NumberN%"
)
goto:eof

Script Output:

Script Output

The next Fibonacci number greater or equal 1000000000 is 1134903170. Press any key to continue . . .

2008-01-01

Summary - Defining a standard format for a DOS batch function

Description:

With the information learned in this section we can define a standard format for a DOS batch functions as shown below.

Also check out the rich set of ready to use DOS functions provided by the DosTips.com .

Script:

Download:

01.
02.
03.
04.
05.
06.
07.
08.
09.
10.
11.

:myFunctionName    -- function description here
::                 -- %~1: argument description here
SETLOCAL
REM.--function body here
set LocalVar1=...
set LocalVar2=...
(ENDLOCAL & REM -- RETURN VALUES
    IF "%~1" NEQ "" SET %~1=%LocalVar1%
    IF "%~2" NEQ "" SET %~2=%LocalVar2%
)
GOTO:EOF